Редактирование стандартных настроек
Стандартные настройки – это настройки, которые делает разработчик в схеме компоновки данных. Средствами встроенного языка можно получить и изменить стандартные настройки схемы компоновки данных. Более подробно этот процесс описан - .
В приведенном ниже примере создается группировка по полю Номенклатура и вложенная в нее группировка по полю Период. Затем создается автополе для списка полей и упорядочивания этих группировок. Затем в общий список выбранных полей добавляется поле ресурса Цена. В заключение задается заголовок и макет оформления отчета (листинг 3.55).
Листинг 3.55. Процедура программной установки настроек
Настройки = СхемаКомпоновкиДанных.НастройкиПоУмолчанию;
ГруппировкаНоменклатура = Настройки.Структура.Добавить(Тип("ГруппировкаКомпоновкиДанных"));
ГруппировкаНоменклатура.Использование = Истина;
ГруппировкаПериод = ГруппировкаНоменклатура.Структура.
Добавить(Тип("ГруппировкаКомпоновкиДанных"));
ГруппировкаПериод.Использование = Истина;
ПолеНоменклатура = ГруппировкаНоменклатура.ПоляГруппировки.Элементы.
Добавить(Тип("ПолеГруппировкиКомпоновкиДанных"));
ПолеНоменклатура.Использование = Истина;
ПолеНоменклатура.Поле = Новый ПолеКомпоновкиДанных("Номенклатура");
ПолеПериод = ГруппировкаПериод.ПоляГруппировки.Элементы.
Добавить(Тип("ПолеГруппировкиКомпоновкиДанных"));
ПолеПериод.Использование = Истина;
ПолеПериод.Поле = Новый ПолеКомпоновкиДанных("Период");
ВыбранныеПоляДляНоменклатуры = ГруппировкаНоменклатура.Выбор.Элементы.
Добавить(Тип("АвтоВыбранноеПолеКомпоновкиДанных"));
ВыбранныеПоляДляНоменклатуры.Использование = Истина;
ПорядокДляНоменклатуры = ГруппировкаНоменклатура.Порядок.Элементы.
Добавить(Тип("АвтоЭлементПорядкаКомпоновкиДанных"));
ПорядокДляНоменклатуры.Использование = Истина;
ВыбранныеПоляДляПериода = ГруппировкаПериод.Выбор.Элементы.
Добавить(Тип("АвтоВыбранноеПолеКомпоновкиДанных"));
ВыбранныеПоляДляПериода.Использование = Истина;
ПорядокДляПериода = ГруппировкаПериод.Порядок.Элементы.
Добавить(Тип("АвтоЭлементПорядкаКомпоновкиДанных"));
ПорядокДляПериода.Использование = Истина;
ВыбранныеПоля = Настройки.Выбор.Элементы.Добавить(Тип("ВыбранноеПолеКомпоновкиДанных"));
ВыбранныеПоля.Использование = Истина;
ВыбранныеПоля.Заголовок = "Цена";
ВыбранныеПоля.Поле = Новый ПолеКомпоновкиДанных("Цена");
Настройки.ПараметрыВывода.УстановитьЗначениеПараметра("Заголовок","Цены комплектующих");
Настройки.ПараметрыВывода.УстановитьЗначениеПараметра("МакетОформления","Зеленый");
Код, представленный в листингах 3.53, 3.54, 3.55, 3.61, реализован в обработке Работа с СКД. В обработке при нажатии кнопки Сформировать отчет полностью программным образом формируется отчет о последних ценах комплектующих из регистра сведений Цены (рис. 3.319).
Рис. 3.319. Обработка «Работа с СКД»
